前回は、ステータスを動かしてみましたが、今回は、それを利用した簡単な勝負や、チャレンジの要素を作ります。

勝ち負け・成功失敗の判定

「ステータスが、○以上なら勝ち（成功）、そうでなければ、負け（失敗）」という要素です。

まずは、育成画面に、「勝負」を実行するボタンを作ってみてください。

（ボタンの作り方→基本の育成画面を作る）

そのリンク先のラベル（たとえば「*勝負」）の下に、次のように記述します。

[if exp="f.パワー >= 50"]
勝負に勝った！[l][cm]
[else]
勝負に負けた…[l][cm]
[endif]
[jump target="*育成画面"  ]

「『パワー』が『50』以上であれば、『勝ち』、そうでなければ『負け』」というものです。

「IF」の細かい使い方は、公式をご覧ください。

https://tyrano.jp/sample2/code/tech/13#demo

ここでは、文字を表示しているだけですが、勝ち負け（成功失敗）によって、ステータスを上下させることも可能です。

前回作ったプログラムを参考に、表示する文字の下に追加してみてください。

複数の条件で判定する

もう少し、複雑な判定方法にすることも可能です。いくつかアイデアを書いておきます。

合計値で判断

「○○と××の合計が、○以上なら勝ち（成功）」というものです。

[eval exp="f.総合力 = f.パワー + f.技術"]
[if exp="f.総合力 >= 100"]
勝負に勝った！[l][cm]
[else]
勝負に負けた…[l][cm]
[endif]
[jump target="*育成画面"  ]

「『パワー』+『技術』が『総合力』で、『総合力』が『100』以上なら『勝ち』」

ここでは、いったん合計値を定義した後、その合計値を利用して、勝負を判定してみました。

複数の条件を満たしたら勝ち

[if exp="f.パワー >= 50 && f.技術 >= 50" ]
勝負に勝った！[l][cm]
[else]
勝負に負けた…[l][cm]
[endif]
[jump target="*育成画面"  ]

「『パワー』が『50』以上、かつ、『技術』が『50』以上であれば、『勝ち』、そうでなければ『負け』」

どちらかの条件を満たしたら勝ち

[eval exp="f.総合力 = f.パワー + f.技術"]
[if exp="f.パワー >= 50 || f.総合力 >= 100" ]
勝負に勝った！[l][cm]
[else]
勝負に負けた…[l][cm]
[endif]
[jump target="*育成画面"  ]

「『パワー』が『50』以上、または、『総合力』が『100』以上であれば、『勝ち』、そうでなければ『負け』」

判定を詳細化

[if exp="f.パワー >= 100" ]
大勝利！[l][cm]
[elsif exp="f.パワー >= 75" ]
勝利！[l][cm]
[elsif exp="f.パワー >= 50" ]
引き分け[l][cm]
[elsif exp="f.パワー >= 25" ]
敗北…[l][cm]
[else]
大敗…[l][cm]
[endif]
[jump target="*育成画面"  ]

単なる勝ち負けだけでなく、大勝利や引き分け、大敗なども追加してみました。

「IF」は、上の条件が優先されるので、順番に気を付けてください。

（例えば、先に「引き分け」の条件を書いてしまうと、どんなにパワーが高くても、「大勝利」や「勝利」にならなくなります。）

○○なら◎◎、△△なら▲▲

[if exp="f.パワー >= 50" ]
力押し！[l][cm]
[elsif exp="f.知力 >= 50" ]
作戦勝ち！[l][cm]
[else]
勝負に負けた…[l][cm]
[endif]
[jump target="*育成画面"  ]

「『パワー』が『50』以上であれば、『力押し』、『知力』が『50』以上であれば、『作戦勝ち』、そうでなければ『負け』」

ちなみに、これだと、パワーの判定が優先されるため、パワーが50以上であれば、どんなに知力が高くとも、「作戦勝ち」にはなりません。

気に入らない方は、下の方法なんてどうでしょう。

条件ごとに判定方法を変える

[if exp="f.パワー > f.知力" ]
[jump  target="*パワー判定"  ]
[else]
[jump  target="*知力判定"  ]
[endif]

これは、「パワーが知力より高ければ、パワーで判定する（ラベルに飛ぶ）、そうでなければ、知力でー」というもの。（数値が同じだと、知力判定になります）

それぞれのラベルの下に、それぞれの判定方法を書いてください。

これらの要素に、ランダム性を持たせて、更に複雑にする方法は、応用編で扱っています。

次回は、ターン制ゲームの仕組みを再現してみます。